home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / usr / lib / perl5 / 5.8.7 / i686-linux-thread-multi / Data / Dumper.pm
Text File  |  2006-04-25  |  38KB  |  1,250 lines
  1. #
  2. # Data/Dumper.pm
  3. #
  4. # convert perl data structures into perl syntax suitable for both printing
  5. # and eval
  6. #
  7. # Documentation at the __END__
  8. #
  9.  
  10. package Data::Dumper;
  11.  
  12. $VERSION = '2.121_04';
  13.  
  14. #$| = 1;
  15.  
  16. use 5.006_001;
  17. require Exporter;
  18. require overload;
  19.  
  20. use Carp;
  21.  
  22. BEGIN {
  23.     @ISA = qw(Exporter);
  24.     @EXPORT = qw(Dumper);
  25.     @EXPORT_OK = qw(DumperX);
  26.  
  27.     # if run under miniperl, or otherwise lacking dynamic loading,
  28.     # XSLoader should be attempted to load, or the pure perl flag
  29.     # toggled on load failure.
  30.     eval {
  31.     require XSLoader;
  32.     };
  33.     $Useperl = 1 if $@;
  34. }
  35.  
  36. XSLoader::load( 'Data::Dumper' ) unless $Useperl;
  37.  
  38. # module vars and their defaults
  39. $Indent     = 2         unless defined $Indent;
  40. $Purity     = 0         unless defined $Purity;
  41. $Pad        = ""        unless defined $Pad;
  42. $Varname    = "VAR"     unless defined $Varname;
  43. $Useqq      = 0         unless defined $Useqq;
  44. $Terse      = 0         unless defined $Terse;
  45. $Freezer    = ""        unless defined $Freezer;
  46. $Toaster    = ""        unless defined $Toaster;
  47. $Deepcopy   = 0         unless defined $Deepcopy;
  48. $Quotekeys  = 1         unless defined $Quotekeys;
  49. $Bless      = "bless"   unless defined $Bless;
  50. #$Expdepth   = 0         unless defined $Expdepth;
  51. $Maxdepth   = 0         unless defined $Maxdepth;
  52. $Pair       = ' => '    unless defined $Pair;
  53. $Useperl    = 0         unless defined $Useperl;
  54. $Sortkeys   = 0         unless defined $Sortkeys;
  55. $Deparse    = 0         unless defined $Deparse;
  56.  
  57. #
  58. # expects an arrayref of values to be dumped.
  59. # can optionally pass an arrayref of names for the values.
  60. # names must have leading $ sign stripped. begin the name with *
  61. # to cause output of arrays and hashes rather than refs.
  62. #
  63. sub new {
  64.   my($c, $v, $n) = @_;
  65.  
  66.   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])" 
  67.     unless (defined($v) && (ref($v) eq 'ARRAY'));
  68.   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  69.  
  70.   my($s) = { 
  71.              level      => 0,           # current recursive depth
  72.          indent     => $Indent,     # various styles of indenting
  73.          pad    => $Pad,        # all lines prefixed by this string
  74.          xpad       => "",          # padding-per-level
  75.          apad       => "",          # added padding for hash keys n such
  76.          sep        => "",          # list separator
  77.          pair    => $Pair,    # hash key/value separator: defaults to ' => '
  78.          seen       => {},          # local (nested) refs (id => [name, val])
  79.          todump     => $v,          # values to dump []
  80.          names      => $n,          # optional names for values []
  81.          varname    => $Varname,    # prefix to use for tagging nameless ones
  82.              purity     => $Purity,     # degree to which output is evalable
  83.              useqq     => $Useqq,      # use "" for strings (backslashitis ensues)
  84.              terse     => $Terse,      # avoid name output (where feasible)
  85.              freezer    => $Freezer,    # name of Freezer method for objects
  86.              toaster    => $Toaster,    # name of method to revive objects
  87.              deepcopy    => $Deepcopy,   # dont cross-ref, except to stop recursion
  88.              quotekeys    => $Quotekeys,  # quote hash keys
  89.              'bless'    => $Bless,    # keyword to use for "bless"
  90. #         expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  91.          maxdepth    => $Maxdepth,   # depth beyond which we give up
  92.          useperl    => $Useperl,    # use the pure Perl implementation
  93.          sortkeys   => $Sortkeys,   # flag or filter for sorting hash keys
  94.          deparse    => $Deparse,    # use B::Deparse for coderefs
  95.        };
  96.  
  97.   if ($Indent > 0) {
  98.     $s->{xpad} = "  ";
  99.     $s->{sep} = "\n";
  100.   }
  101.   return bless($s, $c);
  102. }
  103.  
  104. #
  105. # add-to or query the table of already seen references
  106. #
  107. sub Seen {
  108.   my($s, $g) = @_;
  109.   if (defined($g) && (ref($g) eq 'HASH'))  {
  110.     my($k, $v, $id);
  111.     while (($k, $v) = each %$g) {
  112.       if (defined $v and ref $v) {
  113.     ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
  114.     if ($k =~ /^[*](.*)$/) {
  115.       $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
  116.            (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
  117.            (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
  118.                      (   "\$" . $1 ) ;
  119.     }
  120.     elsif ($k !~ /^\$/) {
  121.       $k = "\$" . $k;
  122.     }
  123.     $s->{seen}{$id} = [$k, $v];
  124.       }
  125.       else {
  126.     carp "Only refs supported, ignoring non-ref item \$$k";
  127.       }
  128.     }
  129.     return $s;
  130.   }
  131.   else {
  132.     return map { @$_ } values %{$s->{seen}};
  133.   }
  134. }
  135.  
  136. #
  137. # set or query the values to be dumped
  138. #
  139. sub Values {
  140.   my($s, $v) = @_;
  141.   if (defined($v) && (ref($v) eq 'ARRAY'))  {
  142.     $s->{todump} = [@$v];        # make a copy
  143.     return $s;
  144.   }
  145.   else {
  146.     return @{$s->{todump}};
  147.   }
  148. }
  149.  
  150. #
  151. # set or query the names of the values to be dumped
  152. #
  153. sub Names {
  154.   my($s, $n) = @_;
  155.   if (defined($n) && (ref($n) eq 'ARRAY'))  {
  156.     $s->{names} = [@$n];         # make a copy
  157.     return $s;
  158.   }
  159.   else {
  160.     return @{$s->{names}};
  161.   }
  162. }
  163.  
  164. sub DESTROY {}
  165.  
  166. sub Dump {
  167.     return &Dumpxs
  168.     unless $Data::Dumper::Useperl || (ref($_[0]) && $_[0]->{useperl}) ||
  169.            $Data::Dumper::Useqq   || (ref($_[0]) && $_[0]->{useqq}) ||
  170.            $Data::Dumper::Deparse || (ref($_[0]) && $_[0]->{deparse});
  171.     return &Dumpperl;
  172. }
  173.  
  174. #
  175. # dump the refs in the current dumper object.
  176. # expects same args as new() if called via package name.
  177. #
  178. sub Dumpperl {
  179.   my($s) = shift;
  180.   my(@out, $val, $name);
  181.   my($i) = 0;
  182.   local(@post);
  183.  
  184.   $s = $s->new(@_) unless ref $s;
  185.  
  186.   for $val (@{$s->{todump}}) {
  187.     my $out = "";
  188.     @post = ();
  189.     $name = $s->{names}[$i++];
  190.     if (defined $name) {
  191.       if ($name =~ /^[*](.*)$/) {
  192.     if (defined $val) {
  193.       $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
  194.           (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
  195.           (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
  196.                       ( "\$" . $1 ) ;
  197.     }
  198.     else {
  199.       $name = "\$" . $1;
  200.     }
  201.       }
  202.       elsif ($name !~ /^\$/) {
  203.     $name = "\$" . $name;
  204.       }
  205.     }
  206.     else {
  207.       $name = "\$" . $s->{varname} . $i;
  208.     }
  209.  
  210.     my $valstr;
  211.     {
  212.       local($s->{apad}) = $s->{apad};
  213.       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
  214.       $valstr = $s->_dump($val, $name);
  215.     }
  216.  
  217.     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
  218.     $out .= $s->{pad} . $valstr . $s->{sep};
  219.     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post) 
  220.       . ';' . $s->{sep} if @post;
  221.  
  222.     push @out, $out;
  223.   }
  224.   return wantarray ? @out : join('', @out);
  225. }
  226.  
  227. #
  228. # twist, toil and turn;
  229. # and recurse, of course.
  230. # sometimes sordidly;
  231. # and curse if no recourse.
  232. #
  233. sub _dump {
  234.   my($s, $val, $name) = @_;
  235.   my($sname);
  236.   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
  237.  
  238.   $type = ref $val;
  239.   $out = "";
  240.  
  241.   if ($type) {
  242.  
  243.     # Call the freezer method if it's specified and the object has the
  244.     # method.  Trap errors and warn() instead of die()ing, like the XS
  245.     # implementation.
  246.     my $freezer = $s->{freezer};
  247.     if ($freezer and UNIVERSAL::can($val, $freezer)) {
  248.       eval { $val->$freezer() };
  249.       warn "WARNING(Freezer method call failed): $@" if $@;
  250.     }
  251.  
  252.     ($realpack, $realtype, $id) =
  253.       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
  254.  
  255.     # if it has a name, we need to either look it up, or keep a tab
  256.     # on it so we know when we hit it later
  257.     if (defined($name) and length($name)) {
  258.       # keep a tab on it so that we dont fall into recursive pit
  259.       if (exists $s->{seen}{$id}) {
  260. #    if ($s->{expdepth} < $s->{level}) {
  261.       if ($s->{purity} and $s->{level} > 0) {
  262.         $out = ($realtype eq 'HASH')  ? '{}' :
  263.           ($realtype eq 'ARRAY') ? '[]' :
  264.         'do{my $o}' ;
  265.         push @post, $name . " = " . $s->{seen}{$id}[0];
  266.       }
  267.       else {
  268.         $out = $s->{seen}{$id}[0];
  269.         if ($name =~ /^([\@\%])/) {
  270.           my $start = $1;
  271.           if ($out =~ /^\\$start/) {
  272.         $out = substr($out, 1);
  273.           }
  274.           else {
  275.         $out = $start . '{' . $out . '}';
  276.           }
  277.         }
  278.           }
  279.       return $out;
  280. #        }
  281.       }
  282.       else {
  283.         # store our name
  284.         $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
  285.                  ($realtype eq 'CODE' and
  286.                   $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
  287.                  $name          ),
  288.                 $val ];
  289.       }
  290.     }
  291.  
  292.     if ($realpack and $realpack eq 'Regexp') {
  293.     $out = "$val";
  294.     $out =~ s,/,\\/,g;
  295.     return "qr/$out/";
  296.     }
  297.  
  298.     # If purity is not set and maxdepth is set, then check depth: 
  299.     # if we have reached maximum depth, return the string
  300.     # representation of the thing we are currently examining
  301.     # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)'). 
  302.     if (!$s->{purity}
  303.     and $s->{maxdepth} > 0
  304.     and $s->{level} >= $s->{maxdepth})
  305.     {
  306.       return qq['$val'];
  307.     }
  308.  
  309.     # we have a blessed ref
  310.     if ($realpack) {
  311.       $out = $s->{'bless'} . '( ';
  312.       $blesspad = $s->{apad};
  313.       $s->{apad} .= '       ' if ($s->{indent} >= 2);
  314.     }
  315.  
  316.     $s->{level}++;
  317.     $ipad = $s->{xpad} x $s->{level};
  318.  
  319.     if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
  320.       if ($realpack) {
  321.     $out .= 'do{\\(my $o = ' . $s->_dump($$val, "\${$name}") . ')}';
  322.       }
  323.       else {
  324.     $out .= '\\' . $s->_dump($$val, "\${$name}");
  325.       }
  326.     }
  327.     elsif ($realtype eq 'GLOB') {
  328.     $out .= '\\' . $s->_dump($$val, "*{$name}");
  329.     }
  330.     elsif ($realtype eq 'ARRAY') {
  331.       my($v, $pad, $mname);
  332.       my($i) = 0;
  333.       $out .= ($name =~ /^\@/) ? '(' : '[';
  334.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  335.       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
  336.     # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
  337.     ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
  338.       ($mname = $name . '->');
  339.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  340.       for $v (@$val) {
  341.     $sname = $mname . '[' . $i . ']';
  342.     $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
  343.     $out .= $pad . $ipad . $s->_dump($v, $sname);
  344.     $out .= "," if $i++ < $#$val;
  345.       }
  346.       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
  347.       $out .= ($name =~ /^\@/) ? ')' : ']';
  348.     }
  349.     elsif ($realtype eq 'HASH') {
  350.       my($k, $v, $pad, $lpad, $mname, $pair);
  351.       $out .= ($name =~ /^\%/) ? '(' : '{';
  352.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  353.       $lpad = $s->{apad};
  354.       $pair = $s->{pair};
  355.       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
  356.     # omit -> if $foo->[0]->{bar}, but not ${$foo->[0]}->{bar}
  357.     ($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
  358.       ($mname = $name . '->');
  359.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  360.       my ($sortkeys, $keys, $key) = ("$s->{sortkeys}");
  361.       if ($sortkeys) {
  362.     if (ref($s->{sortkeys}) eq 'CODE') {
  363.       $keys = $s->{sortkeys}($val);
  364.       unless (ref($keys) eq 'ARRAY') {
  365.         carp "Sortkeys subroutine did not return ARRAYREF";
  366.         $keys = [];
  367.       }
  368.     }
  369.     else {
  370.       $keys = [ sort keys %$val ];
  371.     }
  372.       }
  373.       while (($k, $v) = ! $sortkeys ? (each %$val) :
  374.          @$keys ? ($key = shift(@$keys), $val->{$key}) :
  375.          () ) 
  376.       {
  377.     my $nk = $s->_dump($k, "");
  378.     $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
  379.     $sname = $mname . '{' . $nk . '}';
  380.     $out .= $pad . $ipad . $nk . $pair;
  381.  
  382.     # temporarily alter apad
  383.     $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
  384.     $out .= $s->_dump($val->{$k}, $sname) . ",";
  385.     $s->{apad} = $lpad if $s->{indent} >= 2;
  386.       }
  387.       if (substr($out, -1) eq ',') {
  388.     chop $out;
  389.     $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
  390.       }
  391.       $out .= ($name =~ /^\%/) ? ')' : '}';
  392.     }
  393.     elsif ($realtype eq 'CODE') {
  394.       if ($s->{deparse}) {
  395.     require B::Deparse;
  396.     my $sub =  'sub ' . (B::Deparse->new)->coderef2text($val);
  397.     $pad    =  $s->{sep} . $s->{pad} . $s->{apad} . $s->{xpad} x ($s->{level} - 1);
  398.     $sub    =~ s/\n/$pad/gse;
  399.     $out   .=  $sub;
  400.       } else {
  401.         $out .= 'sub { "DUMMY" }';
  402.         carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
  403.       }
  404.     }
  405.     else {
  406.       croak "Can\'t handle $realtype type.";
  407.     }
  408.     
  409.     if ($realpack) { # we have a blessed ref
  410.       $out .= ', \'' . $realpack . '\'' . ' )';
  411.       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
  412.       $s->{apad} = $blesspad;
  413.     }
  414.     $s->{level}--;
  415.  
  416.   }
  417.   else {                                 # simple scalar
  418.  
  419.     my $ref = \$_[1];
  420.     # first, catalog the scalar
  421.     if ($name ne '') {
  422.       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
  423.       if (exists $s->{seen}{$id}) {
  424.         if ($s->{seen}{$id}[2]) {
  425.       $out = $s->{seen}{$id}[0];
  426.       #warn "[<$out]\n";
  427.       return "\${$out}";
  428.     }
  429.       }
  430.       else {
  431.     #warn "[>\\$name]\n";
  432.     $s->{seen}{$id} = ["\\$name", $ref];
  433.       }
  434.     }
  435.     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
  436.       my $name = substr($val, 1);
  437.       if ($name =~ /^[A-Za-z_][\w:]*$/) {
  438.     $name =~ s/^main::/::/;
  439.     $sname = $name;
  440.       }
  441.       else {
  442.     $sname = $s->_dump($name, "");
  443.     $sname = '{' . $sname . '}';
  444.       }
  445.       if ($s->{purity}) {
  446.     my $k;
  447.     local ($s->{level}) = 0;
  448.     for $k (qw(SCALAR ARRAY HASH)) {
  449.       my $gval = *$val{$k};
  450.       next unless defined $gval;
  451.       next if $k eq "SCALAR" && ! defined $$gval;  # always there
  452.  
  453.       # _dump can push into @post, so we hold our place using $postlen
  454.       my $postlen = scalar @post;
  455.       $post[$postlen] = "\*$sname = ";
  456.       local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
  457.       $post[$postlen] .= $s->_dump($gval, "\*$sname\{$k\}");
  458.     }
  459.       }
  460.       $out .= '*' . $sname;
  461.     }
  462.     elsif (!defined($val)) {
  463.       $out .= "undef";
  464.     }
  465.     elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})\z/) { # safe decimal number
  466.       $out .= $val;
  467.     }
  468.     else {                 # string
  469.       if ($s->{useqq} or $val =~ tr/\0-\377//c) {
  470.         # Fall back to qq if there's unicode
  471.     $out .= qquote($val, $s->{useqq});
  472.       }
  473.       else {
  474.     $val =~ s/([\\\'])/\\$1/g;
  475.     $out .= '\'' . $val .  '\'';
  476.       }
  477.     }
  478.   }
  479.   if ($id) {
  480.     # if we made it this far, $id was added to seen list at current
  481.     # level, so remove it to get deep copies
  482.     if ($s->{deepcopy}) {
  483.       delete($s->{seen}{$id});
  484.     }
  485.     elsif ($name) {
  486.       $s->{seen}{$id}[2] = 1;
  487.     }
  488.   }
  489.   return $out;
  490. }
  491.   
  492. #
  493. # non-OO style of earlier version
  494. #
  495. sub Dumper {
  496.   return Data::Dumper->Dump([@_]);
  497. }
  498.  
  499. # compat stub
  500. sub DumperX {
  501.   return Data::Dumper->Dumpxs([@_], []);
  502. }
  503.  
  504. sub Dumpf { return Data::Dumper->Dump(@_) }
  505.  
  506. sub Dumpp { print Data::Dumper->Dump(@_) }
  507.  
  508. #
  509. # reset the "seen" cache 
  510. #
  511. sub Reset {
  512.   my($s) = shift;
  513.   $s->{seen} = {};
  514.   return $s;
  515. }
  516.  
  517. sub Indent {
  518.   my($s, $v) = @_;
  519.   if (defined($v)) {
  520.     if ($v == 0) {
  521.       $s->{xpad} = "";
  522.       $s->{sep} = "";
  523.     }
  524.     else {
  525.       $s->{xpad} = "  ";
  526.       $s->{sep} = "\n";
  527.     }
  528.     $s->{indent} = $v;
  529.     return $s;
  530.   }
  531.   else {
  532.     return $s->{indent};
  533.   }
  534. }
  535.  
  536. sub Pair {
  537.     my($s, $v) = @_;
  538.     defined($v) ? (($s->{pair} = $v), return $s) : $s->{pair};
  539. }
  540.  
  541. sub Pad {
  542.   my($s, $v) = @_;
  543.   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
  544. }
  545.  
  546. sub Varname {
  547.   my($s, $v) = @_;
  548.   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
  549. }
  550.  
  551. sub Purity {
  552.   my($s, $v) = @_;
  553.   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
  554. }
  555.  
  556. sub Useqq {
  557.   my($s, $v) = @_;
  558.   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
  559. }
  560.  
  561. sub Terse {
  562.   my($s, $v) = @_;
  563.   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
  564. }
  565.  
  566. sub Freezer {
  567.   my($s, $v) = @_;
  568.   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
  569. }
  570.  
  571. sub Toaster {
  572.   my($s, $v) = @_;
  573.   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
  574. }
  575.  
  576. sub Deepcopy {
  577.   my($s, $v) = @_;
  578.   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
  579. }
  580.  
  581. sub Quotekeys {
  582.   my($s, $v) = @_;
  583.   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
  584. }
  585.  
  586. sub Bless {
  587.   my($s, $v) = @_;
  588.   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
  589. }
  590.  
  591. sub Maxdepth {
  592.   my($s, $v) = @_;
  593.   defined($v) ? (($s->{'maxdepth'} = $v), return $s) : $s->{'maxdepth'};
  594. }
  595.  
  596. sub Useperl {
  597.   my($s, $v) = @_;
  598.   defined($v) ? (($s->{'useperl'} = $v), return $s) : $s->{'useperl'};
  599. }
  600.  
  601. sub Sortkeys {
  602.   my($s, $v) = @_;
  603.   defined($v) ? (($s->{'sortkeys'} = $v), return $s) : $s->{'sortkeys'};
  604. }
  605.  
  606. sub Deparse {
  607.   my($s, $v) = @_;
  608.   defined($v) ? (($s->{'deparse'} = $v), return $s) : $s->{'deparse'};
  609. }
  610.  
  611. # used by qquote below
  612. my %esc = (  
  613.     "\a" => "\\a",
  614.     "\b" => "\\b",
  615.     "\t" => "\\t",
  616.     "\n" => "\\n",
  617.     "\f" => "\\f",
  618.     "\r" => "\\r",
  619.     "\e" => "\\e",
  620. );
  621.  
  622. # put a string value in double quotes
  623. sub qquote {
  624.   local($_) = shift;
  625.   s/([\\\"\@\$])/\\$1/g;
  626.   my $bytes; { use bytes; $bytes = length }
  627.   s/([^\x00-\x7f])/'\x{'.sprintf("%x",ord($1)).'}'/ge if $bytes > length;
  628.   return qq("$_") unless 
  629.     /[^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit
  630.  
  631.   my $high = shift || "";
  632.   s/([\a\b\t\n\f\r\e])/$esc{$1}/g;
  633.  
  634.   if (ord('^')==94)  { # ascii
  635.     # no need for 3 digits in escape for these
  636.     s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
  637.     s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
  638.     # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
  639.     if ($high eq "iso8859") {
  640.       s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
  641.     } elsif ($high eq "utf8") {
  642. #     use utf8;
  643. #     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
  644.     } elsif ($high eq "8bit") {
  645.         # leave it as it is
  646.     } else {
  647.       s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
  648.       s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
  649.     }
  650.   }
  651.   else { # ebcdic
  652.       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
  653.        {my $v = ord($1); '\\'.sprintf(($v <= 037 ? '%o' : '%03o'), $v)}eg;
  654.       s{([^ !"\#\$%&'()*+,\-.\/0-9:;<=>?\@A-Z[\\\]^_`a-z{|}~])}
  655.        {'\\'.sprintf('%03o',ord($1))}eg;
  656.   }
  657.  
  658.   return qq("$_");
  659. }
  660.  
  661. # helper sub to sort hash keys in Perl < 5.8.0 where we don't have
  662. # access to sortsv() from XS
  663. sub _sortkeys { [ sort keys %{$_[0]} ] }
  664.  
  665. 1;
  666. __END__
  667.  
  668. =head1 NAME
  669.  
  670. Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
  671.  
  672. =head1 SYNOPSIS
  673.  
  674.     use Data::Dumper;
  675.  
  676.     # simple procedural interface
  677.     print Dumper($foo, $bar);
  678.  
  679.     # extended usage with names
  680.     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  681.  
  682.     # configuration variables
  683.     {
  684.       local $Data::Dumper::Purity = 1;
  685.       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  686.     }
  687.  
  688.     # OO usage
  689.     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
  690.        ...
  691.     print $d->Dump;
  692.        ...
  693.     $d->Purity(1)->Terse(1)->Deepcopy(1);
  694.     eval $d->Dump;
  695.  
  696.  
  697. =head1 DESCRIPTION
  698.  
  699. Given a list of scalars or reference variables, writes out their contents in
  700. perl syntax. The references can also be objects.  The contents of each
  701. variable is output in a single Perl statement.  Handles self-referential
  702. structures correctly.
  703.  
  704. The return value can be C<eval>ed to get back an identical copy of the
  705. original reference structure.
  706.  
  707. Any references that are the same as one of those passed in will be named
  708. C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
  709. to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
  710. notation.  You can specify names for individual values to be dumped if you
  711. use the C<Dump()> method, or you can change the default C<$VAR> prefix to
  712. something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
  713. below.
  714.  
  715. The default output of self-referential structures can be C<eval>ed, but the
  716. nested references to C<$VAR>I<n> will be undefined, since a recursive
  717. structure cannot be constructed using one Perl statement.  You should set the
  718. C<Purity> flag to 1 to get additional statements that will correctly fill in
  719. these references.  Moreover, if C<eval>ed when strictures are in effect,
  720. you need to ensure that any variables it accesses are previously declared.
  721.  
  722. In the extended usage form, the references to be dumped can be given
  723. user-specified names.  If a name begins with a C<*>, the output will 
  724. describe the dereferenced type of the supplied reference for hashes and
  725. arrays, and coderefs.  Output of names will be avoided where possible if
  726. the C<Terse> flag is set.
  727.  
  728. In many cases, methods that are used to set the internal state of the
  729. object will return the object itself, so method calls can be conveniently
  730. chained together.
  731.  
  732. Several styles of output are possible, all controlled by setting
  733. the C<Indent> flag.  See L<Configuration Variables or Methods> below 
  734. for details.
  735.  
  736.  
  737. =head2 Methods
  738.  
  739. =over 4
  740.  
  741. =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
  742.  
  743. Returns a newly created C<Data::Dumper> object.  The first argument is an
  744. anonymous array of values to be dumped.  The optional second argument is an
  745. anonymous array of names for the values.  The names need not have a leading
  746. C<$> sign, and must be comprised of alphanumeric characters.  You can begin
  747. a name with a C<*> to specify that the dereferenced type must be dumped
  748. instead of the reference itself, for ARRAY and HASH references.
  749.  
  750. The prefix specified by C<$Data::Dumper::Varname> will be used with a
  751. numeric suffix if the name for a value is undefined.
  752.  
  753. Data::Dumper will catalog all references encountered while dumping the
  754. values. Cross-references (in the form of names of substructures in perl
  755. syntax) will be inserted at all possible points, preserving any structural
  756. interdependencies in the original set of values.  Structure traversal is
  757. depth-first,  and proceeds in order from the first supplied value to
  758. the last.
  759.  
  760. =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
  761.  
  762. Returns the stringified form of the values stored in the object (preserving
  763. the order in which they were supplied to C<new>), subject to the
  764. configuration options below.  In a list context, it returns a list
  765. of strings corresponding to the supplied values.
  766.  
  767. The second form, for convenience, simply calls the C<new> method on its
  768. arguments before dumping the object immediately.
  769.  
  770. =item I<$OBJ>->Seen(I<[HASHREF]>)
  771.  
  772. Queries or adds to the internal table of already encountered references.
  773. You must use C<Reset> to explicitly clear the table if needed.  Such
  774. references are not dumped; instead, their names are inserted wherever they
  775. are encountered subsequently.  This is useful especially for properly
  776. dumping subroutine references.
  777.  
  778. Expects an anonymous hash of name => value pairs.  Same rules apply for names
  779. as in C<new>.  If no argument is supplied, will return the "seen" list of
  780. name => value pairs, in a list context.  Otherwise, returns the object
  781. itself.
  782.  
  783. =item I<$OBJ>->Values(I<[ARRAYREF]>)
  784.  
  785. Queries or replaces the internal array of values that will be dumped.
  786. When called without arguments, returns the values.  Otherwise, returns the
  787. object itself.
  788.  
  789. =item I<$OBJ>->Names(I<[ARRAYREF]>)
  790.  
  791. Queries or replaces the internal array of user supplied names for the values
  792. that will be dumped.  When called without arguments, returns the names.
  793. Otherwise, returns the object itself.
  794.  
  795. =item I<$OBJ>->Reset
  796.  
  797. Clears the internal table of "seen" references and returns the object
  798. itself.
  799.  
  800. =back
  801.  
  802. =head2 Functions
  803.  
  804. =over 4
  805.  
  806. =item Dumper(I<LIST>)
  807.  
  808. Returns the stringified form of the values in the list, subject to the
  809. configuration options below.  The values will be named C<$VAR>I<n> in the
  810. output, where I<n> is a numeric suffix.  Will return a list of strings
  811. in a list context.
  812.  
  813. =back
  814.  
  815. =head2 Configuration Variables or Methods
  816.  
  817. Several configuration variables can be used to control the kind of output
  818. generated when using the procedural interface.  These variables are usually
  819. C<local>ized in a block so that other parts of the code are not affected by
  820. the change.  
  821.  
  822. These variables determine the default state of the object created by calling
  823. the C<new> method, but cannot be used to alter the state of the object
  824. thereafter.  The equivalent method names should be used instead to query
  825. or set the internal state of the object.
  826.  
  827. The method forms return the object itself when called with arguments,
  828. so that they can be chained together nicely.
  829.  
  830. =over 4
  831.  
  832. =item *
  833.  
  834. $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
  835.  
  836. Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
  837. spews output without any newlines, indentation, or spaces between list
  838. items.  It is the most compact format possible that can still be called
  839. valid perl.  Style 1 outputs a readable form with newlines but no fancy
  840. indentation (each level in the structure is simply indented by a fixed
  841. amount of whitespace).  Style 2 (the default) outputs a very readable form
  842. which takes into account the length of hash keys (so the hash value lines
  843. up).  Style 3 is like style 2, but also annotates the elements of arrays
  844. with their index (but the comment is on its own line, so array output
  845. consumes twice the number of lines).  Style 2 is the default.
  846.  
  847. =item *
  848.  
  849. $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
  850.  
  851. Controls the degree to which the output can be C<eval>ed to recreate the
  852. supplied reference structures.  Setting it to 1 will output additional perl
  853. statements that will correctly recreate nested references.  The default is
  854. 0.
  855.  
  856. =item *
  857.  
  858. $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
  859.  
  860. Specifies the string that will be prefixed to every line of the output.
  861. Empty string by default.
  862.  
  863. =item *
  864.  
  865. $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
  866.  
  867. Contains the prefix to use for tagging variable names in the output. The
  868. default is "VAR".
  869.  
  870. =item *
  871.  
  872. $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
  873.  
  874. When set, enables the use of double quotes for representing string values.
  875. Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
  876. characters will be backslashed, and unprintable characters will be output as
  877. quoted octal integers.  Since setting this variable imposes a performance
  878. penalty, the default is 0.  C<Dump()> will run slower if this flag is set,
  879. since the fast XSUB implementation doesn't support it yet.
  880.  
  881. =item *
  882.  
  883. $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
  884.  
  885. When set, Data::Dumper will emit single, non-self-referential values as
  886. atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
  887. will be avoided where possible, but be advised that such output may not
  888. always be parseable by C<eval>.
  889.  
  890. =item *
  891.  
  892. $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
  893.  
  894. Can be set to a method name, or to an empty string to disable the feature.
  895. Data::Dumper will invoke that method via the object before attempting to
  896. stringify it.  This method can alter the contents of the object (if, for
  897. instance, it contains data allocated from C), and even rebless it in a
  898. different package.  The client is responsible for making sure the specified
  899. method can be called via the object, and that the object ends up containing
  900. only perl data types after the method has been called.  Defaults to an empty
  901. string.
  902.  
  903. If an object does not support the method specified (determined using
  904. UNIVERSAL::can()) then the call will be skipped.  If the method dies a
  905. warning will be generated.
  906.  
  907. =item *
  908.  
  909. $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
  910.  
  911. Can be set to a method name, or to an empty string to disable the feature.
  912. Data::Dumper will emit a method call for any objects that are to be dumped
  913. using the syntax C<bless(DATA, CLASS)-E<gt>METHOD()>.  Note that this means that
  914. the method specified will have to perform any modifications required on the
  915. object (like creating new state within it, and/or reblessing it in a
  916. different package) and then return it.  The client is responsible for making
  917. sure the method can be called via the object, and that it returns a valid
  918. object.  Defaults to an empty string.
  919.  
  920. =item *
  921.  
  922. $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
  923.  
  924. Can be set to a boolean value to enable deep copies of structures.
  925. Cross-referencing will then only be done when absolutely essential
  926. (i.e., to break reference cycles).  Default is 0.
  927.  
  928. =item *
  929.  
  930. $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
  931.  
  932. Can be set to a boolean value to control whether hash keys are quoted.
  933. A false value will avoid quoting hash keys when it looks like a simple
  934. string.  Default is 1, which will always enclose hash keys in quotes.
  935.  
  936. =item *
  937.  
  938. $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
  939.  
  940. Can be set to a string that specifies an alternative to the C<bless>
  941. builtin operator used to create objects.  A function with the specified
  942. name should exist, and should accept the same arguments as the builtin.
  943. Default is C<bless>.
  944.  
  945. =item *
  946.  
  947. $Data::Dumper::Pair  I<or>  $I<OBJ>->Pair(I<[NEWVAL]>)
  948.  
  949. Can be set to a string that specifies the separator between hash keys
  950. and values. To dump nested hash, array and scalar values to JavaScript,
  951. use: C<$Data::Dumper::Pair = ' : ';>. Implementing C<bless> in JavaScript
  952. is left as an exercise for the reader.
  953. A function with the specified name exists, and accepts the same arguments
  954. as the builtin.
  955.  
  956. Default is: C< =E<gt> >.
  957.  
  958. =item *
  959.  
  960. $Data::Dumper::Maxdepth  I<or>  $I<OBJ>->Maxdepth(I<[NEWVAL]>)
  961.  
  962. Can be set to a positive integer that specifies the depth beyond which
  963. which we don't venture into a structure.  Has no effect when
  964. C<Data::Dumper::Purity> is set.  (Useful in debugger when we often don't
  965. want to see more than enough).  Default is 0, which means there is 
  966. no maximum depth. 
  967.  
  968. =item *
  969.  
  970. $Data::Dumper::Useperl  I<or>  $I<OBJ>->Useperl(I<[NEWVAL]>)
  971.  
  972. Can be set to a boolean value which controls whether the pure Perl
  973. implementation of C<Data::Dumper> is used. The C<Data::Dumper> module is
  974. a dual implementation, with almost all functionality written in both
  975. pure Perl and also in XS ('C'). Since the XS version is much faster, it
  976. will always be used if possible. This option lets you override the
  977. default behavior, usually for testing purposes only. Default is 0, which
  978. means the XS implementation will be used if possible.
  979.  
  980. =item *
  981.  
  982. $Data::Dumper::Sortkeys  I<or>  $I<OBJ>->Sortkeys(I<[NEWVAL]>)
  983.  
  984. Can be set to a boolean value to control whether hash keys are dumped in
  985. sorted order. A true value will cause the keys of all hashes to be
  986. dumped in Perl's default sort order. Can also be set to a subroutine
  987. reference which will be called for each hash that is dumped. In this
  988. case C<Data::Dumper> will call the subroutine once for each hash,
  989. passing it the reference of the hash. The purpose of the subroutine is
  990. to return a reference to an array of the keys that will be dumped, in
  991. the order that they should be dumped. Using this feature, you can
  992. control both the order of the keys, and which keys are actually used. In
  993. other words, this subroutine acts as a filter by which you can exclude
  994. certain keys from being dumped. Default is 0, which means that hash keys
  995. are not sorted.
  996.  
  997. =item *
  998.  
  999. $Data::Dumper::Deparse  I<or>  $I<OBJ>->Deparse(I<[NEWVAL]>)
  1000.  
  1001. Can be set to a boolean value to control whether code references are
  1002. turned into perl source code. If set to a true value, C<B::Deparse>
  1003. will be used to get the source of the code reference. Using this option
  1004. will force using the Perl implementation of the dumper, since the fast
  1005. XSUB implementation doesn't support it.
  1006.  
  1007. Caution : use this option only if you know that your coderefs will be
  1008. properly reconstructed by C<B::Deparse>.
  1009.  
  1010. =back
  1011.  
  1012. =head2 Exports
  1013.  
  1014. =over 4
  1015.  
  1016. =item Dumper
  1017.  
  1018. =back
  1019.  
  1020. =head1 EXAMPLES
  1021.  
  1022. Run these code snippets to get a quick feel for the behavior of this
  1023. module.  When you are through with these examples, you may want to
  1024. add or change the various configuration variables described above,
  1025. to see their behavior.  (See the testsuite in the Data::Dumper
  1026. distribution for more examples.)
  1027.  
  1028.  
  1029.     use Data::Dumper;
  1030.  
  1031.     package Foo;
  1032.     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
  1033.  
  1034.     package Fuz;                       # a weird REF-REF-SCALAR object
  1035.     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
  1036.  
  1037.     package main;
  1038.     $foo = Foo->new;
  1039.     $fuz = Fuz->new;
  1040.     $boo = [ 1, [], "abcd", \*foo,
  1041.              {1 => 'a', 023 => 'b', 0x45 => 'c'}, 
  1042.              \\"p\q\'r", $foo, $fuz];
  1043.  
  1044.     ########
  1045.     # simple usage
  1046.     ########
  1047.  
  1048.     $bar = eval(Dumper($boo));
  1049.     print($@) if $@;
  1050.     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
  1051.  
  1052.     $Data::Dumper::Terse = 1;          # don't output names where feasible
  1053.     $Data::Dumper::Indent = 0;         # turn off all pretty print
  1054.     print Dumper($boo), "\n";
  1055.  
  1056.     $Data::Dumper::Indent = 1;         # mild pretty print
  1057.     print Dumper($boo);
  1058.  
  1059.     $Data::Dumper::Indent = 3;         # pretty print with array indices
  1060.     print Dumper($boo);
  1061.  
  1062.     $Data::Dumper::Useqq = 1;          # print strings in double quotes
  1063.     print Dumper($boo);
  1064.  
  1065.     $Data::Dumper::Pair = " : ";       # specify hash key/value separator
  1066.     print Dumper($boo);
  1067.  
  1068.  
  1069.     ########
  1070.     # recursive structures
  1071.     ########
  1072.  
  1073.     @c = ('c');
  1074.     $c = \@c;
  1075.     $b = {};
  1076.     $a = [1, $b, $c];
  1077.     $b->{a} = $a;
  1078.     $b->{b} = $a->[1];
  1079.     $b->{c} = $a->[2];
  1080.     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
  1081.  
  1082.  
  1083.     $Data::Dumper::Purity = 1;         # fill in the holes for eval
  1084.     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
  1085.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
  1086.  
  1087.  
  1088.     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
  1089.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  1090.  
  1091.  
  1092.     $Data::Dumper::Purity = 0;         # avoid cross-refs
  1093.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  1094.  
  1095.     ########
  1096.     # deep structures
  1097.     ########
  1098.  
  1099.     $a = "pearl";
  1100.     $b = [ $a ];
  1101.     $c = { 'b' => $b };
  1102.     $d = [ $c ];
  1103.     $e = { 'd' => $d };
  1104.     $f = { 'e' => $e };
  1105.     print Data::Dumper->Dump([$f], [qw(f)]);
  1106.  
  1107.     $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
  1108.     print Data::Dumper->Dump([$f], [qw(f)]);
  1109.  
  1110.  
  1111.     ########
  1112.     # object-oriented usage
  1113.     ########
  1114.  
  1115.     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
  1116.     $d->Seen({'*c' => $c});            # stash a ref without printing it
  1117.     $d->Indent(3);
  1118.     print $d->Dump;
  1119.     $d->Reset->Purity(0);              # empty the seen cache
  1120.     print join "----\n", $d->Dump;
  1121.  
  1122.  
  1123.     ########
  1124.     # persistence
  1125.     ########
  1126.  
  1127.     package Foo;
  1128.     sub new { bless { state => 'awake' }, shift }
  1129.     sub Freeze {
  1130.         my $s = shift;
  1131.     print STDERR "preparing to sleep\n";
  1132.     $s->{state} = 'asleep';
  1133.     return bless $s, 'Foo::ZZZ';
  1134.     }
  1135.  
  1136.     package Foo::ZZZ;
  1137.     sub Thaw {
  1138.         my $s = shift;
  1139.     print STDERR "waking up\n";
  1140.     $s->{state} = 'awake';
  1141.     return bless $s, 'Foo';
  1142.     }
  1143.  
  1144.     package Foo;
  1145.     use Data::Dumper;
  1146.     $a = Foo->new;
  1147.     $b = Data::Dumper->new([$a], ['c']);
  1148.     $b->Freezer('Freeze');
  1149.     $b->Toaster('Thaw');
  1150.     $c = $b->Dump;
  1151.     print $c;
  1152.     $d = eval $c;
  1153.     print Data::Dumper->Dump([$d], ['d']);
  1154.  
  1155.  
  1156.     ########
  1157.     # symbol substitution (useful for recreating CODE refs)
  1158.     ########
  1159.  
  1160.     sub foo { print "foo speaking\n" }
  1161.     *other = \&foo;
  1162.     $bar = [ \&other ];
  1163.     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
  1164.     $d->Seen({ '*foo' => \&foo });
  1165.     print $d->Dump;
  1166.  
  1167.  
  1168.     ########
  1169.     # sorting and filtering hash keys
  1170.     ########
  1171.  
  1172.     $Data::Dumper::Sortkeys = \&my_filter;
  1173.     my $foo = { map { (ord, "$_$_$_") } 'I'..'Q' };
  1174.     my $bar = { %$foo };
  1175.     my $baz = { reverse %$foo };
  1176.     print Dumper [ $foo, $bar, $baz ];
  1177.  
  1178.     sub my_filter {
  1179.         my ($hash) = @_;
  1180.         # return an array ref containing the hash keys to dump
  1181.         # in the order that you want them to be dumped
  1182.         return [
  1183.           # Sort the keys of %$foo in reverse numeric order
  1184.             $hash eq $foo ? (sort {$b <=> $a} keys %$hash) :
  1185.           # Only dump the odd number keys of %$bar
  1186.             $hash eq $bar ? (grep {$_ % 2} keys %$hash) :
  1187.           # Sort keys in default order for all other hashes
  1188.             (sort keys %$hash)
  1189.         ];
  1190.     }
  1191.  
  1192. =head1 BUGS
  1193.  
  1194. Due to limitations of Perl subroutine call semantics, you cannot pass an
  1195. array or hash.  Prepend it with a C<\> to pass its reference instead.  This
  1196. will be remedied in time, now that Perl has subroutine prototypes.
  1197. For now, you need to use the extended usage form, and prepend the
  1198. name with a C<*> to output it as a hash or array.
  1199.  
  1200. C<Data::Dumper> cheats with CODE references.  If a code reference is
  1201. encountered in the structure being processed (and if you haven't set
  1202. the C<Deparse> flag), an anonymous subroutine that
  1203. contains the string '"DUMMY"' will be inserted in its place, and a warning
  1204. will be printed if C<Purity> is set.  You can C<eval> the result, but bear
  1205. in mind that the anonymous sub that gets created is just a placeholder.
  1206. Someday, perl will have a switch to cache-on-demand the string
  1207. representation of a compiled piece of code, I hope.  If you have prior
  1208. knowledge of all the code refs that your data structures are likely
  1209. to have, you can use the C<Seen> method to pre-seed the internal reference
  1210. table and make the dumped output point to them, instead.  See L<EXAMPLES>
  1211. above.
  1212.  
  1213. The C<Useqq> and C<Deparse> flags makes Dump() run slower, since the
  1214. XSUB implementation does not support them.
  1215.  
  1216. SCALAR objects have the weirdest looking C<bless> workaround.
  1217.  
  1218. Pure Perl version of C<Data::Dumper> escapes UTF-8 strings correctly
  1219. only in Perl 5.8.0 and later.
  1220.  
  1221. =head2 NOTE
  1222.  
  1223. Starting from Perl 5.8.1 different runs of Perl will have different
  1224. ordering of hash keys.  The change was done for greater security,
  1225. see L<perlsec/"Algorithmic Complexity Attacks">.  This means that
  1226. different runs of Perl will have different Data::Dumper outputs if
  1227. the data contains hashes.  If you need to have identical Data::Dumper
  1228. outputs from different runs of Perl, use the environment variable
  1229. PERL_HASH_SEED, see L<perlrun/PERL_HASH_SEED>.  Using this restores
  1230. the old (platform-specific) ordering: an even prettier solution might
  1231. be to use the C<Sortkeys> filter of Data::Dumper.
  1232.  
  1233. =head1 AUTHOR
  1234.  
  1235. Gurusamy Sarathy        gsar@activestate.com
  1236.  
  1237. Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
  1238. This program is free software; you can redistribute it and/or
  1239. modify it under the same terms as Perl itself.
  1240.  
  1241. =head1 VERSION
  1242.  
  1243. Version 2.121  (Aug 24 2003)
  1244.  
  1245. =head1 SEE ALSO
  1246.  
  1247. perl(1)
  1248.  
  1249. =cut
  1250.